I recently updated a Mura CMS site I maintain, by adding a new “portal of portals” section. The main portal listed a series of guest authors that are writing articles for our site. Each author block in the portal list was actually its own portal or article pages. This is all common practice in Mura and in my opinion, one of the areas where it excels at adding content.

All the pages in this section are a two-column, 70/30 layout, with the main content on the left and some author specific information in the right. Both the author article portal list and each article all have the same content on the right, so I made an “authors info” component for that information. This content is a set of the author’s favorite Web sites. To make that content easy for my Editors to maintain, I extended the author’s portal template in the Class Extension Manager, and added new attributes to collect the link information. In my case, I added 10 fields to collect up to 5 links in the form of a Text/URL combination. My attributes are named Link1Text, Link1Url, Link2Text, Link2Url and so on.

So I now have one common “authors info” component in mu Mura admin that I include in the right side of my two column layout. The code view of that component looks like this:

<div class="span-7 last sidebar">
   <img alt="About the Author" src="/xyzsite/assets/Image/sidebars/sidebar_authorsinfo.gif" />

   <p style="font-style: italic;">"Take a look at some of my favorite sites"</p>
   <ul>
	[mura]dspInclude('display_objects/custom/ali/dsp_authorsInfo.cfm')[/mura]
   </ul>

<!--- static content to link users to other author sections --->
   <hr width="50px" />
   <p>See all of our authors pages:</p>
   <ul>
	<li> <a href="/index.cfm/articles/author/Author-A/">Author A</a> </li>
	<li> <a href="/index.cfm/articles/author/Author-B/">Author A</a> </li>
	<li> <a href="/index.cfm/articles/author/Author-C/">Author A</a> </li>
	<li> <a href="/index.cfm/articles/author/Author-D/">Author A</a> </li>
	<li> <a href="/index.cfm/articles/author/Author-E/">Author A</a> </li>
   </ul>
</div>

To pull the links and information into the component, I made a custom Mura display file (a CMF file) that I include in my template. That file started like this:

/xyzsite/includes/display_objects/custom/xyz/dsp_authorsInfo.cfm

<cfloop from="1" to="5" index="x">
   <cfset txt = $.content('Link'&x&'Text')/>
   <cfset lnk = $.content('Link'&x&'Url')/>

   <cfif (len(txt) GT 0) AND (len(lnk) GT 0)>
      <cfoutput>
           <li><a href="#lnk#">#txt#</a></li>
      </cfoutput>
   </cfif>
</cfloop>

In my Extended Attributes I have fields that collect a link and the text to hyperlink for up to 5 links. So here I run a loop from 1 to 5, set my link and text values, and then if both have content I add them as a list item.

When i saved all of this and reloaded an author’s portal page, I saw my links loaded as expected. However, when I opened an actual article written by that author, all I saw at the on the right was “Take a look at some of my favorite sites” then nothing. That is because my extended attributes are part of the main portal page and not the article sub-page. If you look at the code, I am loading Mura’s “content” object. The Mura Programer’s Guide explains that the “…Content scope wraps the CURRENT front end request’s contentBean”. So when I look at the portal page, where the custom link attributes are defined, they are available in the content scope.

So, if I can only get the currently loaded page’s info in the content bean, then how can I get the content from other pages? In my case, the Programmer’s Guide led me to a very simple solution: call the parent object using the getParent() method of the $.content() method. Doing this will return the data from the current’s page’s parent page as a contentBean. With that knowledge I updated my custom display file as so:

/xyzsite/includes/display_objects/custom/xyz/dsp_authorsInfo.cfm

<cfloop from="1" to="5" index="x">
<cfsilent>
   <cfset page = ListLast(cgi.PATH_INFO,'/') />

   <cfif  (page IS 'Author-A')
       OR (page IS 'Author-B')
       OR (page IS 'Author-C')
       OR (page IS 'Author-D')
       OR (page IS 'Author-E')
   >
     <!--- user is on a author portal page where the link values are available --->
     <cfset txt = $.content('Link'&x&'Text')/>
     <cfset lnk = $.content('Link'&x&'Url')/>
   <cfelse>
     <!--- user is on a article page, so grab info from the parent --->
     <cfset parentBn = $.content().getParent() />
     <cfset txt = parentBn.getValue('Link'&x&'Text')/>
     <cfset lnk = parentBn.getValue('Link'&x&'Url')/>
   </cfif>

   <cfif (len(lnk) GT 0) AND (lnk CONTAINS 'mysitedomain.com')>
       <cfset openIn = "_self" />
   <cfelse>
       <cfset openIn = "_blank" />
   </cfif>
</cfsilent>
   <cfif (len(txt) GT 0) AND (len(lnk) GT 0)>
       <cfoutput>
          <li><a href="#lnk#" target="#openIn#">#txt#</a></li>
       </cfoutput>
   </cfif>
</cfloop>

As you can see, at the top I updated my code to determine if the right side component was being loaded on an author’s page, by looking at a CGI var. If so, I set my links the same way I did originally. If not, then I assume the right side component is being loaded on a nested article page, so I first get my parent page’s contentBean, then set my links that way. In addition, I added some code to determine my link’s target value.

This all seems to work well. I would like to dig a little deeper and find out if I can dynamically find out how many attributes my page has. That way I wouldn’t need to hard code the 1 to 5 loop, and could easily add more link pairs in the future.